Import the data

If the data stored in “goodmuon2.txt” is contained in the same directory as the mathematica notebook then this filename will work

filename = StringJoin[NotebookDirectory[],"goodmuon2.txt"]

goodmuon2 = Import[filename, "Table"];

Show the first 10 rows in “TableForm”

goodmuon2[[1;;10,;;]]//TableForm

Select out all rows, taking only columns 2 through 5.
Flatten the table into one long list.

goodmuon3 = Flatten[goodmuon2[[;;,2;;5]]];
goodmuon3[[1;;8]]//TableForm

Construct time array, data table, and weights

According to Jason and Brian the time step was 0.095 microseconds.  
Construct the time array.

dt = 0.095*^-6  ; (*time steps in seconds*)
time = Table[dt*i,{i,1,Length[goodmuon3]}];

ListPlot[] requires pairs of (x,y) values for plotting, so this table constructs an array of the appropriate form:

data = Transpose[{time,goodmuon3}];
data[[1;;6]](*Display the first few points*)
ListLogPlot[data,PlotRange->All]

The first few data points look questinoable.  Call the trimmed data set “datatrimmed”

dataTrimmed = data[[20;;220]];
ListLogPlot[dataTrimmed,PlotRange->All]

Construct the weights array using the following form for a Possion distribution

({{({{weights=(1/(σ^2))}})=(1/(number of counts))
error = σ = (Sqrt[number of counts])}})

The “number of counts” is given in the second column of the array “datatrimmed”.

error = (Sqrt[dataTrimmed[[;;,2]] ]); 
weights = 1/(error^2)  ;

Make a plot with error bars

I am ashamed to say it, but Mathematica can only make error bars on plots with linear-linear axes

Installing the Mathematica “Error Bar Log Plots Package”

The download is from http://library.wolfram.com/infocenter/MathSource/6747/
Title		Error Bar Log Plots for Mathematica 6
Author	Frank Rice
Organization: 	California Institute of Technology
Department: 	Physics
Revision date:	2007-05-29
Description:		
ErrorBarLogPlots.m is a package which adds log-scale plotting functions similar to the standard ErrorListPlot provided in Mathematica 6. The added functions are ErrorListLogPlot, ErrorListLogLinearPlot, and ErrorListLogLogPlot.

To install the package you have two options:
1) Open the notebook “ErrorBarLogPlots_Installer.nb” which is part of the download and let it auto-run to install the package.
2) 	(a) Go to File->Install..   
	(b) Select Type of Item to Install “Package”
	(c) Select Source “From File”
	(d) Navigate to where the package was downloaded and select the package “ErrorBarLogPlots.m”
	(e) Select “OK”

Loading and Using the ErrorBarLogPlots package

This loads the package so the new functions can be called

Needs["ErrorBarLogPlots`"]

Here is the help entry for ErrorListLogPlot

?ErrorListLogPlot

Before the plot can be made, and appropriate array of data and ErrorBars must be constructed:
the form is { {{x1,y1},ErrorBar[e1]}, {{x2,y2},ErrorBar[e2]},... }

dataTrimmedError = Table[{dataTrimmed[[i]],ErrorBar[ error[[i]] ]},{i,1,Length[dataTrimmed]}];
dataTrimmedError[[1;;5]]

dataErrorPlot = ErrorListLogPlot[dataTrimmedError]

Fitting

LinearModelFit  and NonlinearModelFit are the two best fitting function in Mathematica.  They return a function which can be evaluated and also a set of properties which are documented in the help for getting the parameter errors and covariance matrix.

fit =NonlinearModelFit[dataTrimmed,A*Exp[-t/τ]+C,{{A,5000},{τ,2*^-6},{C,5}},t,Weights->weights]
fitplot = LogPlot[fit[t],{t,0,20*^-6},PlotRange->All,PlotStyle->{Thickness[0.005], Red}]
Show[dataErrorPlot,fitplot]

Nice and common ways to display the fit parameters and errors

A more complete list of the properties is found in the help or at http://reference.wolfram.com/mathematica/ref/NonlinearModelFit.html  
Look under the “MORE INFORMATION” section.

fit["BestFitParameters"]
fit["ParameterErrors"]
fit["ParameterTable"]
fit["CovarianceMatrix"]//TableForm

Modestly Sweeter Looking Plots in Mathematica

You can comment or uncomment any of the lines in plotOptions below to see what effect it has on the aesthetic appeal of the graph.
This is a very convenient way to handle plot options in Mathematica, because this plotOptions list which I created can be reused for many plots without retyping a bunch of options.

plotOptions = {Frame->True,
PlotRange->All,
FrameLabel->{"Time (s)", "Counts per bin"},
(*GridLines->Automatic,*)
Axes->None,
LabelStyle->{FontFamily->"Arial", FontSize->12},
ImageSize->600};
Show[fitplot,dataErrorPlot,plotOptions]

The annotated plot shown below took a few additional quick steps:
1) Copy the plot above and paste it into a new cell (This is optional, but prevents the annotated plot from being rewritten if the Show statement is re-executed)
2) Copy the Table of fit parameters from above, and paste it into the plot
3) Open up the Drawing Tools by right clicking on the plot and selecting “Drawing Tools”.
4) Click on the “Mathematical Text” button that looks like